Resolved How to pass enum type to a function

[silverblatt]

I have a need to retrieve the name associated with a given value in a particular enum (the enum is named FormMode). I can retrieve the name using this code:

[Enum].GetName(GetType(FormMode), enum_item_value)

This works but the syntax strikes me as a little cumbersome, so I wrote a wrapper function to make my code easier to understand:

Public Function GetItemName(ItemValue As Int32) As String
    Return [Enum].GetName(GetType(FormMode), ItemValue)
End Function

This also works, but now I want to generalize the function so that it will do the same job for ANY enum. I've tried this:

Public Function GetItemName2(EN As System.Enum, ItemValue As Int32) As String
    Return [Enum].GetName(GetType(EN), ItemValue)
End Function

but it produces the error "Type 'EN' is not defined." with EN underlined in red in the RETURN statement. I get the same error when I change the parameter type from System.Enum to System.Type.

How can I pass the specific enum as a parameter in such a way that it can be used by the GetType method?

 

[jmcilhinney]

You can cast an Integer as an Enum type, so you could just use DirectCast(enum_item_value, FormMode).ToString()

If you really want to go with your own method then you need an actual data type to pass to GetType. The correct way to do that would be to make your method generic:

Public Function GetItemName(Of TEnum)(ItemValue As Int32) As String
    Return [Enum].GetName(GetType(TEnum), ItemValue)
End Function

TEnum is now an actual data type, i.e. something that you could declare a variable as, e.g.

Dim var As TEnum

so it is valid to be passed to GetType. You would then call that method like so:

Dim formModeName = GetItemName(Of FormMode)(enum_item_value)

The main issue with this method is that it could be called with any data type at all, so including those that are not Enum types. That would cause an exception to be thrown so, if an invalid type is a possibility, you should handle that exception. You'd have to do that with your original code anyway.

 

[JohnH]

Is generics really needed here?

Public Function GetItemName(value As [Enum]) As String
    Return [Enum].GetName(value.GetType, value)
End Function

 

[silverblatt]

Both of these approaches work for me. Thanks jmcilhinney and JohnH!

 

[jmcilhinney]

Is generics really needed here?

Public Function GetItemName(value As [Enum]) As String
    Return [Enum].GetName(value.GetType, value)
End Function

If the original value is an Integer then yes. I surmised that that was the case from the type of the ItemValue parameter. If the OP is saying that both approaches work then I must assume that the original enum_item_value is actually an Enum type and not an Integer. In that case, we can go back to the idea that I originally had and simply use enum_item_value.ToString(), so no custom methods are required at all.

 

[silverblatt]

The enum's member's values are integers.

 

[jmcilhinney]

The enum's member's values are integers.

That doesn't matter. What matters is the type of the enum_item_value variable. If it is type FormMode then calling its ToString method will return the name of the enumerated value. If it's Integer then it will be treated like any other number.

 

[JohnH]

Yes of course, besides ToString will also work for combined flags enum values, GetName will not.